[ASP Picking List
[ Demonstration
;
; Sample Power Portable program for running picking lists on uploaded data.
; Program has the ability to search and enquire on picked products.
;
; Use XMOD or PUTDATA to upload the data file "UPLOAD.SDF"
;
Define 4,16,4,4,4
;
:Menu1
Getc "Start Picking?"
If $k = "Y" then goto StartPicking
If $k = "N" then goto Menu2
If $k = "" then goto Menu2
Beep x
Goto Menu1
;
:Menu2
Getc "Picking Enquiry?"
If $k = "Y" then goto StartEnquiry
If $k = "N" then goto Menu1
If$k = "" then goto Menu1
Beep x
Goto Menu2
;
:StartPicking
If count < 1 then goto PickingError
Get 1
;
:StartPickingLoop
If val(#4) = 0 then goto EnterPickedQty
;
:AfterPickedQty
Skip
If eof then goto EofEnterPickedQty
Goto StartPickingLoop
;
:EofEnterPickedQty
Beep 5
Display "All Items have  been displayed"
Wait(20)
Goto Menu2
;
:EnterPickedQty
Display1 "Product No"
Display2 #0
Wait(15)
Display1 "Description"
Display2 #1
Wait(15)
Display1 "Location"
Display2 #2
Wait(15)
Display1 "Order Quantity"
Display2 #3
Wait(15)
;
Display "Enter Supply Qty"
Input
If $k = "" then goto Menu1
If $k = "0" then goto ContQty
If val($k) > 0 then goto ContQty
Beep x
Goto EnterPickedQty
;
:ContQty
$1 = $k
If val($1) > val(#3) then goto PickedOverSupply
;
:PickedSaveData
#4 = $1
Put
Goto AfterPickedQty
;
:PickedOverSupply
Beep x
Getc "Picked Qty >    than Request Ok?"
If $k = "Y" then goto PickedSaveData
If $k = "N" then goto EnterPickedQty
Beep x
Goto PickedOverSupply
;
:PickingError
Display "No Data Records Loaded! Use XMOD"
Beep x
Wait(20)
Goto Menu1
;
:StartEnquiry
Display "Scan Product No"
Input
$0 = $K
If $0 = "" then goto Menu2
;
; %0 = mid
; %1 = low
; %2 = high
; $0 = data to find
;
%1 = 1
%2 = count
;
:Findpart
%0 = %1 + ((%2 - %1) / 2)
;
GET %0
;
IF #0 = $0 GOTO found
If %1 = %2 goto EofEnquiry
If %2 = 0 goto EofEnquiry
IF #0 > $0 THEN %2 = %0 - 1
IF #0 < $0 THEN %1 = %0 + 1
GOTO findpart
;
:Found
Beep
Display1 "Product No"
Display2 #0
Wait(10)
Display1 "Description"
Display2 #1
Wait(10)
Display1 "Location"
Display2 #2
Wait(10)
Display1 "Order Quantity"
Display2 #3
Wait(10)
Display1 "Supplied Qty"
Display2 #4
Wait(10)
Goto SuppliedQty
;
:EofEnquiry
Display1 "Product not"
Display2 "found in file"
Beep x
Wait(15)
Goto startEnquiry
;
:SuppliedQty
Display "Enter Quantity"	
Input
$1 = $k
;
If val($1) > val(#3) then goto OverSupply
;
If $1 = "" then goto StartEnquiry
;
:SaveData
#4 = $1
Put
Goto StartEnquiry
;
:OverSupply
Beep x
Getc "Picked Qty >    than Request Ok?"
If $k = "Y" then goto SaveData
If $k = "N" then goto SuppliedQty
Beep x
Goto OverSupply
;
END